• ⊞ Win+⇧ Shift+S – nástroj pro screenshot. Totéž bez klávesové zkratky:

• ⊞ Win+V – historie schránky

• Okna a panely
  • Alt+Tab – přepínání oken (na touchpadu: tažení třemi prsty do stran)
  • ⊞ Win+Tab – přepínání oken + historie (na touchpadu: tažení třemi prsty nahoru)
  • Ctrl+Tab – přepínání panelů prohlížeče
• Znaky
  • AltGr+Něco – např. \ | € × [ ] $ ß # & @ { } < > (viz modré znaky na obrázku klávesnice).
  • Všechny znaky viz Emoji Picker (⊞ Win+.).
• Výběr
  • Ctrl+A – vybrat vše
  • ⇧ Shift+Šipka – výběr (po jednotlivých znacích)
  • Ctrl+⇧ Shift+Šipka – výběr (po celých slovech)
  • Ctrl+Del – smazat celé slovo (podobně Ctrl+⌫)
  • F2 – editace
• touchpad (dotyková gesta):
  • klepnutí jedním prstem – výběr
  • klepnutí dvěma prsty – místní nabídka (jako pravé myšítko)
  • klepnutí třemi a čtyřmi prsty – nastavte si sami ve Windows (⊞ Win → „Nastavení touchpadu“)
  • tažení dvěma prsty – posunutí obrazovky
  • roztažení prstů × to stejné s Ctrl: dva různé zoomy, viz SOGo mail (klávesová zkratka Ctrl++ a Ctrl+-)

Automatizace rutinních úkonů ve Windows s využitím zdarma dostupného¹⁾ programu AutoHotkey (stále používám v1.1 ❕). Libovolná klávesová zkratka, posloupnost znaků či kliknutí myši provede (v libovolné aplikaci) libovolnou akci – např.: vloží obsah schránky jako prostý text, spustí spořič obrazovky, vloží definovaný text (např. české uvozovky, nezlomitelnou mezeru, písmeno řecké abecedy, texty pro vyplňování formulářů, zdvořilostní fráze do e‑mailu). Dále např. zrušení klávesy Caps Lock, klikací makra.

Jiný stručný návod v češtině (Daniel Gamrot)

Stáhnout a „instalovat“ program + můj skript ²⁾ – Celý obsah archívu autohotkey.zip je třeba rozbalit do jedné libovolné složky. Skript můžete upravovat přímo (například v Poznámkovém bloku) či po kliknutí pravým myšítkem na ikonu spuštěného programu v oznamovací oblasti (na monitoru vpravo dole). Změny je třeba vždy uložit a skript znovu načíst (Reload This Script):

Obsah skriptu AutoHotkeyU64.ahk (zvýraznění syntaxe je lehce matoucí):

; Řádek začínající středníkem je určen pro poznámky a program jej ignoruje.
 
; Zde dva nepovinné řádky:
#Warn           ; Program hlásí nejen chyby, ale i varování.
SendMode Input  ; Nastavení pro větší rychlost a spolehlivost.
 
; Komentář:	Posloupnost znaků "tultul" na klávesnici
;               → napíše text "Technická univerzita v Liberci"
::tultul::Technická univerzita v Liberci
 
; Kdybych to udělal na jeden řádek bez "send", tak by za vloženým textem byla mezera.
; "tulmail" na klávesnici → vloží "kamil.nesetril@tul.cz"
::tulmail::
send kamil.nesetril@tul.cz
return
 
;               U velkých písmen s háčkem se vkládá háček samostatně. 
::sp::
send S pozdravem{enter}Simona {ˇ}Skodová
return
 
;         	Při pozdravu chci pokračovat na dalším řádku, tak vložím i Enter.
::dd::
send Dobrý den,{enter}
return
 
;         	Vloží "Kamil Nešetřil" (Ctrl + K)
^k::
send Kamil Nešetřil
return
 
;         	Vloží PSČ TUL
::psctul::
send 46117
return
 
;         	Vloží zvláštní znaky UNICODE.
;		První znak je: „Mathematical Script Capital K“.
; https://en.wikipedia.org/wiki/Mathematical_Alphanumeric_Symbols#Latin_letters
::knkn::
send 𝒦𝒩
return
 
;         	Šipka
::-->::
send →
return
 
;         	Pomlčka
::--::–
 
;         	Řecká abeceda
::mímí::μ
::alfaalfa::α
::thetatheta::θ
::lambdalambda::λ
::pípí::π
::róró::ρ
::psípsí::ψ
 
;         	České uvozovky dole (Win + ů)
#ů::
send „
return
 
;         	České uvozovky nahoře (Win + §)
#§::
send “
return
 
;         	Nezlomitelná mezera (Ctrl + Shift + mezera)
^+Space::
send % Chr( 160 )
return
 
;         	Nezlomitelný spojovník (hyphen) (Ctrl + Shift + -)
^+-::
send % Chr( 8209 )
return
 
;         	Nezlomitelná pomlčka (Ctrl + Shift + .)
^+.::
send % Chr( 8288 ) ; nezlomitelný znak
send % Chr( 8211 ) ; pomlčka
send % Chr( 8288 ) ; nezlomitelný znak
return
 
;         	Vloží smajlíka :-) (CapsLock)
Capslock::
send {SHIFTDOWN}.{SHIFTUP}
send -)
return
 
;         	Vloží mrkajícího smajlíka ;-) (Levý Shift + CapsLock).
; Apostrof (tzv. escape character) před středníkem umožní vložit středník,
; který by jinak označoval začátek komentáře.
LShift & Capslock::
send `;-)
return
 
;         	Mé telefonní číslo (Win + T)
#t::
send {+}420724435408
return
 
;         	Vloží jako prostý text (Win + B).
; Jak to funguje: Obsah schránky uložím do proměnné a zase zpět, čímž přijde o formátování.
; Pozor! Při použití v Excelu bere pouze zobrazenou část čísla (např. 1,35 nikoliv 1,35782).
#b::
promenna = %Clipboard%
Clipboard = %promenna%
send ^v
return
 
;         	Vloží můj podpis v angličtině (Win + E).
#e::
send Kamil Nešetřil{enter}
send tel: {+}420 724 435 408{enter}
send Technical University of Liberec, Studentská 2, 461 17 Reichenberg, Czechia
return
 
;         	Spustí šetřič obrazovky (Win + S).
; Příkaz "sleep" zastaví program na 500 ms, aby uživatel stačil uvolnit klávesu.
; Puštěním klávesy by totiž opět probudil obrazovku.
#s::
sleep 500
run scrnsave.scr /start
return
 
;         	Přepnutí aktivního okna vždy na vrch (Win + PgUp)
#PgUp::
WinSet,AlwaysOnTop,Toggle, A
return
 
;		Na numerické klávesnici je desetinná tečka, nikoliv desetinná čárka.
NumpadDot::.
 
;         	Příklad jakési automatizace v Excelu:
;               Zavře soubor a minimalizuje okno aplikace (Win + Esc).
#Esc::
send {CTRLDOWN}{F4}{CTRLUP}
send n
WinMinimize A
return
 
 
;  - - - - - - - - - - - - - - - - - - - - - - - - - - -
;    Bonus – Grafické uživatelské rozhraní (Win + O)
;  - - - - - - - - - - - - - - - - - - - - - - - - - - -
 
#o::
gui, add, edit, vedit1,BMW 			;search Google
gui, add, button, ,Google
gui, add, edit, vedit2,Mercedes		        ;search Bing
gui, add, button, ,Bing
gui, add, DDL,vdd_var gdd_label ,Google|Bing
gui, show, autosize
return
 
buttonGoogle:
gui, submit, nohide
run, https://www.google.com/search?q=%edit1%
return
 
buttonBing:
gui, submit, nohide
run, https://www.bing.com/search?q=%edit2%
return
 
dd_label:
gui, submit, nohide
if dd_var = google
	run, https://www.google.com/search?q=%edit1%
if dd_var = bing
	run, https://www.bing.com/search?q=%edit2%
return

Další tipy na klávesové zkratky: Číslo karty, hesla, číslo občanky, zrušení klávesy Num Lock, přerušení nahrávání v OBS …

Typografie (- – × „ “ nezlomitelná mezera, Shift+Enter zalomení řádku, nadpisy nepodtrhávat, typy písem) 👁^{3) 4)}

Spustit AutoHotkey při spuštění počítače: přidat zástupce souboru AutoHotkeyU64.exe do složky Startup čili Po spuštění. Umístění složky bývá různé, proto složku otevřeme tak, že do ⊞ Win+R napíšeme shell:startup (viz Návod).

Aby byla neustále vidět ikona běžícího AutoHotkey: System tray → Nastavení hlavního panelu → Vybrat, které ikony se budou zobrazovat na hlavním panelu.

Pokud chceme rozšířit klávesnici a přiřadit tlačítkům funkce pomocí AutoHotkey, je možné dokoupit hardware či využít aplikaci na mobilu.

Aplikace v radiologii: myš se spoustou tlačítek a další klávesnice (včetně ukázky kódu v AutoHotkey – supplemental material).

• Pulover's Macro Creator – pokročilé grafické uživatelské rozhraní pro nahrávání maker a pro interaktivní tvorbu skriptů (video tutorial), ⁵⁾
• či jen jednoduchý skript pro záznam stisků kláves a pohybu myši (mé „distro“).